免費(fèi)AI編程助手
Shell文本處理三劍客（三）
防偽碼：鋤禾日當(dāng)午，汗滴禾下土。
8.3.7 7 內(nèi)置函數(shù)
函數(shù) 描述
int(expr) 截?cái)酁檎麛?shù)
sqrt(expr) 平方根
rand() 返回一個(gè)隨機(jī)數(shù) N，0 和 1 范圍，0 < N < 1
srand([expr])
使用 expr 生成隨機(jī)數(shù)，如果不指定，默認(rèn)使用當(dāng)前時(shí)間為種子，如
果前面有種子則使用生成隨機(jī)數(shù)
asort(a, b)
對數(shù)組 a 的值進(jìn)行排序，把排序后的值存到新的數(shù)組 b 中，新排序
的數(shù)組下標(biāo)從 1 開始
asorti(a,b) 對數(shù)組 a 的下標(biāo)進(jìn)行排序，同上
sub(r, s [, t])
對輸入的記錄用 s 替換 r，t 可選針對某字段替換 ，但只替換第一
個(gè)字符串
gsub(r,s [, t]) 對輸入的記錄用 s 替換 r，t 可選針對某字段替換，替換所有字符串
index(s, t) 返回 s 中字符串 t 的索引位置，0 為不存在
length([s]) 返回 s 的長度
match(s, r [, a]) 測試字符串 s 是否包含匹配 r 的字符串
split(s, a [, r [,
seps] ])
根據(jù)分隔符 seps 將 s 分成數(shù)組 a
substr(s, i [, n]) 截取字符串 s 從 i 開始到長度 n，如果 n 沒指定則是剩余部分
tolower(str) str 中的所有大寫轉(zhuǎn)換成小寫
toupper(str) str 中的所有小寫轉(zhuǎn)換成大寫
systime() 當(dāng)前時(shí)間戳
strftime([format [,
timestamp[, utc-
flag]]])
格式化輸出時(shí)間，將時(shí)間戳轉(zhuǎn)為字符串
示例：
1）int()
# echo "123abc abc123 123abc123" |xargs -n1 | awk '{print int($0)}'
123
0
123
# awk 'BEGIN{print int(10/3)}'
3
2）sqrt()
獲取 9 的平方根：
# awk 'BEGIN{print sqrt(9)}'
3
3）rand()和 srand()
rand()并不是每次運(yùn)行就是一個(gè)隨機(jī)數(shù)，會(huì)一直保持一個(gè)不變：
# awk 'BEGIN{print rand()}'
0.237788
當(dāng)執(zhí)行 srand()函數(shù)后，rand()才會(huì)發(fā)生變化，所以一般在 awk 著兩個(gè)函數(shù)結(jié)合生成隨機(jī)數(shù)，但是
也有很大幾率生成一樣：
# awk 'BEGIN{srand();print rand()}'
0.31687
如果想生成 1-10 的隨機(jī)數(shù)可以這樣：
# awk 'BEGIN{srand();print int(rand()*10)}'
4
如果想更完美生成隨機(jī)數(shù)，還得做相應(yīng)的處理！
4）asort()和 asorti()
# seq -f "str%.g" 5 |awk '{a[x++]=$0}END{s=asort(a,b);for(i=1;i<=s;i++)print
b[i],i}'
str1 1
str2 2
str3 3
str4 4
str5 5
# seq -f "str%.g" 5 |awk '{a[x++]=$0}END{s=asorti(a,b);for(i=1;i<=s;i++)print
b[i],i}'
0 1
1 2
2 3
3 4
4 5
asort 將 a 數(shù)組的值放到數(shù)組 b，a 下標(biāo)丟棄，并將數(shù)組 b 的總行號(hào)賦值給 s，新數(shù)組 b 下標(biāo)從 1 開
始，然后遍歷。
5）sub()和 gsub()
# tail /etc/services |awk '/blp5/{sub(/tcp/,"icmp");print $0}'
blp5 48129/icmp # Bloomberg locator
blp5 48129/udp # Bloomberg locator
# tail /etc/services |awk '/blp5/{gsub(/c/,"9");print $0}'
blp5 48129/t9p # Bloomberg lo9ator
blp5 48129/udp # Bloomberg lo9ator
# echo "1 2 2 3 4 5" |awk 'gsub(2,7,$2){print $0}'
1 7 2 3 4 5
# echo "1 2 3 a b c" |awk 'gsub(/[0-9]/, '0'){print $0}'
0 0 0 a b c
在指定行前后加一行：
# seq 5 | awk 'NR==2{sub('/.*/',"txt\n&")}{print}'
1
txt
2
3
4
5
# seq 5 | awk 'NR==2{sub('/.*/',"&\ntxt")}{print}'
1
2
txt
3
4
5
6）index()
# tail -n 5 /etc/services |awk '{print index($2,"tcp")}'
7
0
7
0
7
7）length()
# tail -n 5 /etc/services |awk '{print length($2)}'
9
9
9
9
9
統(tǒng)計(jì)數(shù)組的長度：
# tail -n 5 /etc/services |awk '{a[$1]=$2}END{print length(a)}'
3
8）split()
# echo -e "123#456#789\nabc#cde#fgh" |awk '{split($0,a);for(v in a)print a[v],v}'
123#456#789 1
abc#cde#fgh 1
# echo -e "123#456#789\nabc#cde#fgh" |awk '{split($0,a,"#");for(v in a)print a[v],v}'
123 1
456 2
789 3
abc 1
cde 2
fgh 3
9）substr()
# echo -e "123#456#789\nabc#cde#fgh" |awk '{print
substr($0,4)}'
#456#789
#cde#fgh
# echo -e "123#456#789\nabc#cde#fgh" |awk '{print substr($0,4,5)}'
#456#
#cde#
10）tolower()和 toupper()
# echo -e "123#456#789\nABC#cde#fgh" |awk '{print tolower($0)}'
123#456#789
abc#cde#fgh
# echo -e "123#456#789\nabc#cde#fgh" |awk '{print toupper($0)}'
123#456#789
ABC#CDE#FGH
11)時(shí)間處理
返回當(dāng)前時(shí)間戳：
# awk 'BEGIN{print systime()}'
1483297766
將時(shí)間戳轉(zhuǎn)為日期和時(shí)間
# echo "1483297766" |awk '{print strftime("%Y-%m-%d %H:%M:%S",$0)}'
2017-01-01 14:09:26
8.3.8 8 O I/O 語句
語句 描述
getline 讀取下一個(gè)輸入記錄設(shè)置給$0
getline var 讀取下一個(gè)輸入記錄并賦值給變量 var
command | getline [var] 運(yùn)行 Shell 命令管道輸出到$0 或 var
next 停止當(dāng)前處理的輸入記錄后面動(dòng)作
print 打印當(dāng)前記錄
printf fmt, expr-list 格式化輸出
printf fmt, expr-list >file 格式輸出和寫到文件
system(cmd-line) 執(zhí)行命令和返回狀態(tài)
print ... >> file 追加輸出到文件
print ... | command 打印輸出作為命令輸入
示例：
1）getline
獲取匹配的下一行：
# seq 5 |awk '/3/{getline;print}'
4
# seq 5 |awk '/3/{print;getline;print}'
3
4
在匹配的下一行加個(gè)星號(hào)：
# seq 5 |awk '/3/{getline;sub(".*","&*");print}'
4*
# seq 5 |awk '/3/{print;getline;sub(".*","&*")}{print}'
1
2
3
4*
5
2）getline var
把 a 文件的行追加到 b 文件的行尾：
# cat a
a
b
c
# cat b
1 one
2 two
3 three
# awk '{getline line<"a";print $0,line}' b
1 one a
2 two b
3 three c
把 a 文件的行替換 b 文件的指定字段：
# awk '{getline line<"a";gsub($2,line,$2);print}' b
1 a
2 b
3 c
把 a 文件的行替換 b 文件的對應(yīng)字段：
# awk '{getline line<"a";gsub("two",line,$2);print}' b
1 one
2 b
3 three
3）command | getline [var]
獲取執(zhí)行 shell 命令后結(jié)果的第一行：
# awk 'BEGIN{"seq 5"|getline var;print var}'
1
循環(huán)輸出執(zhí)行 shell 命令后的結(jié)果：
# awk 'BEGIN{while("seq 5"|getline)print}'
1
2
3
4
5
4）next
不打印匹配行：
# seq 5 |awk '{if($0==3){next}else{print}}'
1
2
4
5
刪除指定行：
# seq 5 |awk 'NR==1{next}{print $0}'
2
3
4
5
如果前面動(dòng)作成功，就遇到 next，后面的動(dòng)作不再執(zhí)行，跳過。
或者：
# seq 5 |awk 'NR!=1{print}'
2
3
4
5
把第一行內(nèi)容放到每行的前面：
# cat a
hello
1 a
2 b
3 c
# awk 'NR==1{s=$0;next}{print s,$0}' a
hello 1 a
hello 2 b
hello 3 c
# awk 'NR==1{s=$0}NF!=1{print s,$0}' a
hello 1 a
hello 2 b
hello 3 c
5）system()
執(zhí)行 shell 命令判斷返回值：
# awk 'BEGIN{if(system("grep root /etc/passwd &>/dev/null")==0)print "yes";else print
"no"}'
yes
6）打印結(jié)果寫到文件
# tail -n5 /etc/services |awk '{print $2 > "a.txt"}'
# cat a.txt
48049/tcp
48128/tcp
48128/udp
48129/tcp
48129/udp
7）管道連接 shell 命令
將結(jié)果通過 grep 命令過濾：
# tail -n5 /etc/services |awk '{print $2|"grep tcp"}'
48556/tcp
48619/tcp
49000/tcp
8.3.9 9 f printf 語句
格式化輸出，默認(rèn)打印字符串不換行。
格式：printf [format] arguments
Format 描述
%s 一個(gè)字符串
%d，%i 一個(gè)小數(shù)
%f 一個(gè)浮點(diǎn)數(shù)
%.ns 輸出字符串，n 是輸出幾個(gè)字符
%ni 輸出整數(shù)，n 是輸出幾個(gè)數(shù)字
%m.nf 輸出浮點(diǎn)數(shù)，m 是輸出整數(shù)位數(shù)，n 是輸出的小數(shù)位數(shù)
%x 不帶正負(fù)號(hào)的十六進(jìn)制，使用 a 至 f 表示 10 到 15
%X 不帶正負(fù)號(hào)的十六進(jìn)制，使用 A 至 F 表示 10 至 15
%% 輸出單個(gè)%
%-5s 左對齊，對參數(shù)每個(gè)字段左對齊,寬度為 5
%-4.2f 左對齊，寬度為 4，保留兩位小數(shù)
%5s 右對齊，不加橫線表示右對齊
示例：
將換行符換成逗號(hào)：
# seq 5 |awk '{if($0!=5)printf "%s,",$0;else print $0}'
1,2,3,4,5
小括號(hào)中的 5 是最后一個(gè)數(shù)字。
輸出一個(gè)字符：
# awk 'BEGIN{printf "%.1s\n","abc"}'
a
保留一個(gè)小數(shù)點(diǎn)：
# awk 'BEGIN{printf "%.2f\n",10/3}'
3.33
格式化輸出：
# awk 'BEGIN{printf "user:%s\tpass:%d\n","abc",123}'
user:abc pass:123
左對齊寬度 10：
# awk 'BEGIN{printf "%-10s %-10s %-10s\n","ID","Name","Passwd"}'
ID Name Passwd
右對齊寬度 10：
# awk 'BEGIN{printf "%10s %10s %10s\n","ID","Name","Passwd"}'
ID Name Passwd
打印表格：
# vi test.awk
BEGIN{
print "+--------------------+--------------------+";
printf "|%-20s|%-20s|\n","Name","Number";
print "+--------------------+--------------------+";
}
# awk -f test.awk
+--------------------+--------------------+
|Name |Number |
+--------------------+--------------------+
格式化輸出：
# awk -F: 'BEGIN{printf "UserName\t\tShell\n-----------------------------\n"}{printf
"%-20s %-20s\n",$1,$7}END{print "END...\n"}' /etc/passwd
打印十六進(jìn)制：
# awk 'BEGIN{printf "%x %X",123,123}'
7b 7B
8.3. 10 自定義 函數(shù)
格式：function name(parameter list) { statements }
示例：
# awk 'function myfunc(a,b){return a+b}BEGIN{print myfunc(1,2)}'
3
8.3.11 1 需求案例
1）分析 Nginx 日志
日志格式：
'$remote_addr - $remote_user [$time_local] "$request" $status $body_bytes_sent "
$http_referer" "$http_user_agent" "$http_x_forwarded_for"'
統(tǒng)計(jì)訪問 IP 次數(shù)：
# awk '{a[$1]++}END{for(v in a)print v,a[v]}' access.log
統(tǒng)計(jì)訪問訪問大于 100 次的 IP：
# awk '{a[$1]++}END{for(v in a){if(a[v]>100)print v,a[v]}}' access.log
統(tǒng)計(jì)訪問 IP 次數(shù)并排序取前 10：
# awk '{a[$1]++}END{for(v in a)print v,a[v] |"sort -k2 -nr |head -10"}' access.log
統(tǒng)計(jì)時(shí)間段訪問最多的 IP：
# awk '$4>="[02/Jan/2017:00:02:00" && $4<="[02/Jan/2017:00:03:00"{a[$1]++}END{for(v in
a)print v,a[v]}' access.log
統(tǒng)計(jì)上一分鐘訪問量：
# date=$(date -d '-1 minute' +%d/%d/%Y:%H:%M)
# awk -vdate=$date '$4~date{c++}END{print c}' access.log
統(tǒng)計(jì)訪問最多的 10 個(gè)頁面：
# awk '{a[$7]++}END{for(v in a)print v,a[v] |"sort -k1 -nr|head -
n10"}' access.log
統(tǒng)計(jì)每個(gè) URL 數(shù)量和返回內(nèi)容總大小：
# awk '{a[$7]++;size[$7]+=$10}END{for(v in a)print a[v],v,size[v]}' access.log
統(tǒng)計(jì)每個(gè) IP 訪問狀態(tài)碼數(shù)量：
# awk '{a[$1" "$9]++}END{for(v in a)print v,a[v]}' access.log
統(tǒng)計(jì)訪問 IP 是 404 狀態(tài)次數(shù)：
# awk '{if($9~/404/)a[$1" "$9]++}END{for(i in a)print v,a[v]}' access.log
2）兩個(gè)文件對比
找出 b 文件在 a 文件相同記錄：
# seq 1 5 > a
# seq 3 7 > b
方法 1：
# awk 'FNR==NR{a[$0];next}{if($0 in a)print $0}' a b
3
4
5
# awk 'FNR==NR{a[$0];next}{if($0 in a)print FILENAME,$0}' a b
b 3
b 4
b 5
# awk 'FNR==NR{a[$0]}NR>FNR{if($0 in a)print $0}' a b
3
4
5
# awk 'FNR==NR{a[$0]=1;next}(a[$0]==1)' a b # a[$0]是通過 b 文件每行獲取值，如果是 1
說明有
# awk 'FNR==NR{a[$0]=1;next}{if(a[$0]==1)print}' a b
3
4
5
方法 2：
# awk 'FILENAME=="a"{a[$0]}FILENAME=="b"{if($0 in a)print $0}' a b
3
4
5
方法 3：
# awk 'ARGIND==1{a[$0]=1}ARGIND==2 && a[$0]==1' a b
3
4
5
找出 b 文件在 a 文件不同記錄：
方法 1：
# awk 'FNR==NR{a[$0];next}!($0 in a)' a b
6
7
# awk 'FNR==NR{a[$0]=1;next}(a[$0]!=1)' a b
# awk 'FNR==NR{a[$0]=1;next}{if(a[$0]!=1)print}' a b
6
7
方法 2：
# awk 'FILENAME=="a"{a[$0]=1}FILENAME=="b" && a[$0]!=1' a b
方法 3：
# awk 'ARGIND==1{a[$0]=1}ARGIND==2 && a[$0]!=1' a b
3）合并兩個(gè)文件
將 a 文件合并到 b 文件：
# cat a
zhangsan 20
lisi 23
wangwu 29
# cat b
zhangsan man
lisi woman
wangwu man
# awk 'FNR==NR{a[$1]=$0;next}{print a[$1],$2}' a b
zhangsan 20 man
lisi 23 woman
wangwu 29 man
# awk 'FNR==NR{a[$1]=$0}NR>FNR{print a[$1],$2}' a b
zhangsan 20 man
lisi 23 woman
wangwu 29 man
將 a 文件相同 IP 的服務(wù)名合并：
# cat a
192.168.1.1: httpd
192.168.1.1: tomcat
192.168.1.2: httpd
192.168.1.2: postfix
192.168.1.3: mysqld
192.168.1.4: httpd
# awk 'BEGIN{FS=":";OFS=":"}{a[$1]=a[$1] $2}END{for(v in a)print v,a[v]}' a
192.168.1.4: httpd
192.168.1.1: httpd tomcat
192.168.1.2: httpd postfix
192.168.1.3: mysqld
說明：數(shù)組 a 存儲(chǔ)是$1=a[$1] $2，第一個(gè) a[$1]是以第一個(gè)字段為下標(biāo)，值是 a[$1] $2，也就是
$1=a[$1] $2，值的 a[$1]是用第一個(gè)字段為下標(biāo)獲取對應(yīng)的值，但第一次數(shù)組 a 還沒有元素，那么
a[$1]是空值，此時(shí)數(shù)組存儲(chǔ)是 192.168.1.1=httpd，再遇到 192.168.1.1 時(shí)，a[$1]通過第一字段
下標(biāo)獲得上次數(shù)組的 httpd，把當(dāng)前處理的行第二個(gè)字段放到上一次同下標(biāo)的值后面，作為下標(biāo)
192.168.1.1 的新值。此時(shí)數(shù)組存儲(chǔ)是 192.168.1.1=httpd tomcat。每次遇到相同的下標(biāo)（第一個(gè)
字段）就會(huì)獲取上次這個(gè)下標(biāo)對應(yīng)的值與當(dāng)前字段并作為此下標(biāo)的新值。
4）將第一列合并到一行
# cat file
1 2 3
4 5 6
7 8 9
# awk '{for(i=1;i<=NF;i++)a[i]=a[i]$i" "}END{for(v in a)print a[v]}' file
1 4 7
2 5 8
3 6 9
說明：
for 循環(huán)是遍歷每行的字段，NF 等于 3，循環(huán) 3 次。
讀取第一行時(shí)：
第一個(gè)字段：a[1]=a[1]1" " 值 a[1]還未定義數(shù)組，下標(biāo)也獲取不到對應(yīng)的值，所以為空，因此
a[1]=1 。
第二個(gè)字段：a[2]=a[2]2" " 值 a[2]數(shù)組 a 已經(jīng)定義，但沒有 2 這個(gè)下標(biāo)，也獲取不到對應(yīng)的
值，為空，因此 a[2]=2 。
第三個(gè)字段：a[3]=a[3]3" " 值 a[2]與上面一樣，為空,a[3]=3 。
讀取第二行時(shí)：
第一個(gè)字段：a[1]=a[1]4" " 值 a[2]獲取數(shù)組 a 的 2 為下標(biāo)對應(yīng)的值，上面已經(jīng)有這個(gè)下標(biāo)了，
對應(yīng)的值是 1，因此 a[1]=1 4
第二個(gè)字段：a[2]=a[2]5" " 同上，a[2]=2 5
第三個(gè)字段：a[3]=a[3]6" " 同上，a[2]=3 6
讀取第三行時(shí)處理方式同上，數(shù)組最后還是三個(gè)下標(biāo)，分別是 1=1 4 7，2=2 5 8，3=3 6 9。最后
for 循環(huán)輸出所有下標(biāo)值。
5）字符串拆分，統(tǒng)計(jì)出現(xiàn)的次數(shù)
字符串拆分：
方法 1：
# echo "hello world" |awk -F '' '{print $1}'
h
# echo "hello" |awk -F '' '{for(i=1;i<=NF;i++)print $i}'
h
e
l
l
o
方法 2：
# echo "hello" |awk '{split($0,a,"''");for(v in a)print a[v]}'
l
o
h
e
l
統(tǒng)計(jì)字符串中每個(gè)字母出現(xiàn)的次數(shù)：
# echo "a.b.c,c.d.e" |awk -F '[.,]' '{for(i=1;i<=NF;i++)a[$i]++}END{for(v in a)print
v,a[v]}'
a 1
b 1
c 2
d 1
e 1
5）費(fèi)用統(tǒng)計(jì)
# cat a
zhangsan 8000 1
zhangsan 5000 1
lisi 1000 1
lisi 2000 1
wangwu 1500 1
zhaoliu 6000 1
zhaoliu 2000 1
zhaoliu 3000 1
# awk '{name[$1]++;cost[$1]+=$2;number[$1]+=$3}END{for(v in name)print
v,cost[v],number[v]}' a
zhangsan 5000 1
lisi 3000 2
wangwu 1500 1
zhaoliu 11000 3
6）獲取數(shù)字字段最大值
# cat a
a b 1
c d 2
e f 3
g h 3
i j 2
獲取第三字段最大值：
# awk 'BEGIN{max=0}{if($3>max)max=$3}END{print max}' a
3
打印第三字段最大行：
# awk 'BEGIN{max=0}{a[$0]=$3;if($3>max)max=$3}END{for(v in a)print v,a[v],max}' a
g h 3 3 3
e f 3 3 3
c d 2 2 3
a b 1 1 3
i j 2 2 3
# awk 'BEGIN{max=0}{a[$0]=$3;if($3>max)max=$3}END{for(v in a)if(a[v]==max)print v}' a
g h 3
e f 3
7）去除第一行和最后一行
# seq 5 |awk 'NR>2{print s}{s=$0}'
2
3
4
讀取第一行，NR=1，不執(zhí)行 print s，s=1
讀取第二行，NR=2，不執(zhí)行 print s，s=2 （大于為真）
讀取第三行，NR=3，執(zhí)行 print s，此時(shí) s 是上一次 p 賦值內(nèi)容 2，s=3
最后一行，執(zhí)行 print s，打印倒數(shù)第二行，s=最后一行
獲取 Nginx 負(fù)載均衡配置端 IP 和端口：
# cat nginx.conf
upstream example-servers1 {
server 127.0.0.1:80 weight=1 max_fails=2 fail_timeout=30s;
}
upstream example-servers2 {
server 127.0.0.1:80 weight=1 max_fails=2 fail_timeout=30s;
server 127.0.0.1:82 backup;
}
# awk '/example-servers1/,/}/{if(NR>2){print s}{s=$2}}' nginx.conf
127.0.0.1:80
# awk '/example-servers1/,/}/{if(i>1)print s;s=$2;i++}' nginx.conf
# awk '/example-servers1/,/}/{if(i>1){print s}{s=$2;i++}}' nginx.conf
127.0.0.1:80
讀取第一行，i 初始值為 0，0>1 為假，不執(zhí)行 print s，x=example-servers1，i=1
讀取第二行，i=1，1>1 為假，不執(zhí)行 print s，s=127.0.0.1:80,i=2
讀取第三行，i=2，2>1 為真，執(zhí)行 print s，此時(shí) s 是上一次 s 賦值內(nèi)容 127.0.0.1:80，i=3
最后一行，執(zhí)行 print s，打印倒數(shù)第二行，s=最后一行。
這種方式與上面一樣，只是用 i++作為計(jì)數(shù)器。
8）知道上述方式，就可以實(shí)現(xiàn)這種需求了，打印匹配行的上一行
# seq 5 |awk '/3/{print s}{s=$0}'
2
謝謝觀看，真心的希望能幫到您！
本文出自 “一盞燭光” 博客，謝絕轉(zhuǎn)載！
更多建議：